ASP實例教程：Form集合－Web Design

Form集合

注意因為本ASP實例教程是關於表單的代碼，為了省事，所以我不截圖了！大家自行測試實例執行結果！

一個Form集合的簡單應用

本例演示Form集合如何從表單取回值。此表單使用POST方法，這意味著發送的資訊對用戶來說是不可見的，並且對對所發送資訊的量沒有限制（可發送大量的資訊）。

本示例代碼如下：

<html>
<body>
<form action="/example/aspe/demo_aspe_simpleform1.asp" method="post">
First name:
<input type="text" name="fname" value="Donald" />
<br />
Last name:
<input type="text" name="lname" value="Duck" />
<br />
<input type="submit" value="Submit" />
</form>
<%
Response.Write(Request.Form)
%>
</body>
</html>

如何使用來自表單的資訊

本例演示如何使用從表單取回的資訊。我們使用了Form集合。表單使用了POST方法。

本示例代碼如下：

<html>
<body>
<form action="/example/aspe/demo_aspe_simpleform.asp" method="post">
您的姓名：<input type="text" name="fname" size="20" />
<input type="submit" value="提交" />
</form>
<%
dim fname
fname=Request.Form("fname")
If fname<>"" Then
Response.Write("您好！" & fname & "！<br />")
Response.Write("今天過得怎麼樣？")
End If
%>
</body>
</html>

來自表單的更多資訊

本例演示假如若干的輸入域使用了相同的名稱，Form集合會包含什麼資訊。它將展示如何把這些相同的名稱分割開來。它也會展示如何使用count關鍵詞來對"name"屬性進行計數。此表單使用POST方法。

本示例代碼如下：

<html>
<body>
<form action="/example/aspe/demo_aspe_form2.asp" method="post">
First name:
<input type="text" name="name" value="Donald" />
<br />
Last name:
<input type="text" name="name" value="Duck" />
<br />
<input type="submit" value="Submit" />
</form>
<hr />
<p>來自上面的表單的資訊：</p>
<%
If Request.Form("name")<>"" Then
      Response.Write("<p>")
      Response.Write("name=" & Request.Form("name"))
      Response.Write("</p><p>")
      Response.Write("name 屬性的數目：")
      Response.Write(Request.Form("name").Count)
      Response.Write("</p><p>")
      Response.Write("First name=" & Request.Form("name")(1))
      Response.Write("</p><p>")
      Response.Write("Last name=" & Request.Form("name")(2))
      Response.Write("</p>")
End if
%>
</body>
</html>

帶有單選按鈕的表單

本例演示如何使用Form集合通過單選按鈕與用戶進行交互。此表單使用POST方法。

本示例代碼如下：

<html>
<%
dim cars
cars=Request.Form("cars")
%>
<body>
<form action="/example/aspe/demo_aspe_radiob.asp" method="post">
<p>請選擇您喜歡的汽車：</p>
<input type="radio" name="cars"
<%if cars="Volvo" then Response.Write("checked")%>
value="Volvo">Volvo</input>
<br />
<input type="radio" name="cars"
<%if cars="Saab" then Response.Write("checked")%>
value="Saab">Saab</input>
<br />
<input type="radio" name="cars"
<%if cars="BMW" then Response.Write("checked")%>
value="BMW">BMW</input>
<br /><br />
<input type="submit" value="提交" />
</form>
<%
if cars<>"" then
Response.Write("<p>您喜歡的汽車是" & cars & "</p>")
end if
%>
</body>
</html>

帶有覆選按鈕的表單

本例演示如何使用Form集合通過覆選按鈕與用戶進行交互。此表單使用POST方法。

本示例代碼如下：

<html>
<body>
<%
fruits=Request.Form("fruits")
%>
<form action="/example/aspe/demo_aspe_checkboxes.asp" method="post">
<p>您喜歡哪些水果：</p>
<input type="checkbox" name="fruits" value="Apples"
<%if instr(fruits,"Apple") then Response.Write("checked")%>>
Apple
<br>
<input type="checkbox" name="fruits" value="Oranges"
<%if instr(fruits,"Oranges") then Response.Write("checked")%>>
Orange
<br>
<input type="checkbox" name="fruits" value="Bananas"
<%if instr(fruits,"Banana") then Response.Write("checked")%>>
Banana
<br>
<input type="submit" value="提交">
</form>
<%
if fruits<>"" then%>
<p>您喜歡：<%Response.Write(fruits)%></p>
<%end if
%>
</body>
</html>